%% @author Marc Worrell <marc@worrell.nl>
%% @copyright 2009-2026 Marc Worrell
%% @doc Validator for checking if an input value is within a certain length range
%% @end

%% Copyright 2009-2026 Marc Worrell
%%
%% Licensed under the Apache License, Version 2.0 (the "License");
%% you may not use this file except in compliance with the License.
%% You may obtain a copy of the License at
%%
%%     http://www.apache.org/licenses/LICENSE-2.0
%%
%% Unless required by applicable law or agreed to in writing, software
%% distributed under the License is distributed on an "AS IS" BASIS,
%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
%% See the License for the specific language governing permissions and
%% limitations under the License.

-module(validator_base_length).
-moduledoc("
Check the length of a text input.

Test if the length of the input’s value is more than a minimum and/or less than a maximum length.

Arguments are minimum and maximum. You can give either or both arguments.

For example, a summary that is neither too long nor too short:


```django
<textarea id=\"summary\" name=\"summary\"></textarea>
{% validate id=\"summary\" type={length minimum=20 maximum=200} %}
```



Arguments
---------

| Argument                 | Description                                                                      | Example      |
| ------------------------ | -------------------------------------------------------------------------------- | ------------ |
| is                       | Use when the value must be a specific length.                                    | `is=4`       |
| minimum                  | The minimum length of the value.                                                 | `minimum=4`  |
| maximum                  | The maximum length of the value.                                                 | `maximum=10` |
| wrong\\\\_length\\\\_message | Message for when the length is unequal to the value of the “is” argument. Defaults to “Must be . characters long.” |              |
| too\\\\_short\\\\_message    | Message for when there are not enough characters entered. Defaults to “Must not be less than . characters long.” |              |
| too\\\\_long\\\\_message     | Message for when there are too many characters entered. Defaults to “Must not be more than . characters long.” |              |

See also

[Forms and validation](/id/doc_developerguide_forms_and_validation#guide-validators)").
-include_lib("zotonic_core/include/zotonic.hrl").
-export([render_validator/5, validate/5]).

render_validator(length, TriggerId, _TargetId, Args, _Context)  ->
    Min        = proplists:get_value(minimum, Args),
    Max        = proplists:get_value(maximum, Args),
	JsObject   = z_utils:js_object(z_validation:rename_args(Args)),
	Script     = [<<"z_add_validator(\"">>,TriggerId,<<"\", \"length\", ">>, JsObject, <<");\n">>],
	{[to_number(Min),to_number(Max)], Script}.


-spec validate(term(), term(), term(), list(), z:context()) ->
    {{ok, term()}, z:context()} | {{error, term(), term()}, z:context()}.
%%          Error = invalid | novalue | {script, Script}
validate(length, Id, Value, [Min,Max], Context) when is_list(Value); is_binary(Value) ->
    case z_string:len(Value) of
        0 ->
            {{ok, Value}, Context};
        Len ->
            MinOK = (Min == -1 orelse Len >= Min),
            MaxOK = (Max == -1 orelse Len =< Max),
            case MinOK andalso MaxOK of
                true  -> {{ok, Value}, Context};
                false -> {{error, Id, invalid}, Context}
            end
    end.

to_number(undefined) -> -1;
to_number(N) when is_integer(N) -> N;
to_number(N) -> z_convert:to_integer(N).