defmodule NLdoc.Spec.UnorderedList do
  @moduledoc """
  This module defines the Ecto schema for the NLdoc spec UnorderedList object.
  """
  use NLdoc.Spec.Schema, type: "https://spec.nldoc.nl/Resource/UnorderedList"

  alias NLdoc.Spec.ListItem

  @style_types [:disc, :circle, :square]
  @type style_type :: :disc | :circle | :square

  # coveralls-ignore-next-line Guard functions cannot be covered by ExCoveralls
  defguard is_unordered_list_style(style) when is_atom(style) and style in @style_types

  typed_embedded_schema null: false do
    field :id, Ecto.UUID
    field :type, :string, default: @resource_type
    field :style_type, Ecto.Enum, values: @style_types, default: :disc

    embeds_many :children, ListItem

    field(:descriptors, {:array, PolymorphicEmbed},
      types: map(NLdoc.Spec.descriptors()),
      type_field_name: :type,
      on_replace: :delete,
      default: [],
      array?: true
    ) :: [NLdoc.Spec.descriptor()]
  end

  def changeset(object, attrs) do
    object
    |> cast(attrs, [:id, :type, :style_type], @cast_opts)
    |> cast_embed(:children)
    |> cast_polymorphic_embed(:descriptors, @cast_opts)
    |> validate_required([:id, :type])
    |> validate_inclusion(:type, [@resource_type])
  end
end