-module(exodus_mysql).

-behaviour(exodus_driver).

-export([up/1, down/1, list/1, add/3, delete/2, last/1, exec/2]).

-spec exec(any(), iodata()) -> ok | {error, any()}.
exec(Conn, Query) ->
    case mysql:query(Conn, Query, []) of
        {error, _Err} = E ->
            E;
        ok ->
            ok
    end.

-spec up(any()) -> ok | {error, any()}.
up(Conn) ->
    case mysql:query(Conn,
                     [<<"CREATE TABLE IF NOT EXISTS __exodus_migrations ( ">>,
                      <<"  id SERIAL PRIMARY KEY, ">>,
                      <<"  name TEXT NOT NULL, ">>,
                      <<"  timestamp INTEGER NOT NULL ">>,
                      <<")">>],
                     [])
    of
        {error, _Err} = E ->
            E;
        ok ->
            ok
    end.

-spec down(any()) -> ok | {error, any()}.
down(Conn) ->
    case mysql:query(Conn, <<"DROP TABLE IF EXISTS __exodus_migrations">>, []) of
        {error, _Err} = E ->
            E;
        ok ->
            ok
    end.

-spec list(any()) -> {ok, list()} | {error, any()}.
list(Conn) ->
    case mysql:query(Conn,
                     <<"SELECT id, name, timestamp FROM __exodus_migrations ORDER BY timestamp ASC">>,
                     [])
    of
        {error, _Err} = E ->
            E;
        {ok, _, Rows} ->
            {ok, format_rows(Rows)}
    end.

-spec format_rows(list()) -> list().
format_rows(Rows) ->
    lists:map(fun format_row/1, Rows).

-spec format_row(list()) -> {integer(), module(), integer()} | {error, invalid_row}.
format_row([Id, Name, Timestamp]) ->
    {Id, binary_to_atom(Name), Timestamp};
format_row(_) ->
    {error, invalid_row}.

-spec add(any(), binary(), integer()) -> ok | {error, any()}.
add(Conn, Name, Timestamp) ->
    case mysql:query(Conn,
                     <<"INSERT INTO __exodus_migrations (name, timestamp) VALUES (?, ?)">>,
                     [Name, Timestamp])
    of
        {error, _Err} = E ->
            E;
        ok ->
            ok
    end.

-spec last(any()) -> {error, any()} | {ok, {integer(), module(), integer()}}.
last(Conn) ->
    case mysql:query(Conn,
                     <<"SELECT id, name, timestamp FROM __exodus_migrations ORDER BY timestamp DESC LIMIT 1">>,
                     [])
    of
        {error, _Err} = E ->
            E;
        {ok, _, [[Id, Name, Timestamp]]} ->
            {ok, {Id, binary_to_atom(Name), Timestamp}}
    end.

-spec delete(any(), integer()) -> ok | {error, any()}.
delete(Conn, Id) ->
    case mysql:query(Conn, <<"DELETE FROM __exodus_migrations WHERE id = ?">>, [Id]) of
        {error, _Err} = E ->
            E;
        ok ->
            ok
    end.