Defines the behavior and utilities for Readmix generators.

Generators are modules that implement this behaviour and provide actions that can be invoked from documents.

To create a generator, use:

defmodule MyGenerator do
  use Readmix.Generator

  @doc "This action does something"
  action :my_action,
    as: :generate_my,
    params: [
      param1: [type: :string, doc: "Parameter documentation"]
    ]

  @moduledoc """
  My custom actions.

  #{Readmix.Docs.generate()}
  """

  defp generate_my(params, context) do
    {:ok, "Generated content"}
  end
end

This is equivalent to the following:

defmodule MyGenerator do
  @behaviour Readmix.Generator

  @actions [
    my_action: [
      params: [
        param1: [type: :string, doc: "Parameter documentation"]
      ],
      doc: "This action does something"
    ]
  ]

  @moduledoc """
  My custom actions.

  #{Readmix.Docs.generate(@actions)}
  """

  @impl true
  def actions, do: @actions

  @impl true
  def generate(:my_action, params, context) do
    generate_my(params, context)
  end

  defp generate_my(params, context) do
    {:ok, "Generated content"}
  end
end