Helpers for bulk-action lifecycle hook authors.

The 3-arity variants of :on_bulk_action_success and :on_bulk_action_error (and the unarchive conflict-skip success branch) receive (summary, state, socket) and can return either:

• a plain socket — the core handler then fires its default flash (e.g. "3 succeeded, 2 failed" on partial, or the error flash).
• {:halt, socket} — the core handler skips the default flash; the hook is fully responsible for messaging.

Use silence/1 for the halt path and (optionally) use_default/1 as a documentation-friendly no-op when you want the default flash to fire.

Examples

Replace the default with a custom message:

hooks do
  on_bulk_action_success :master_unarchive, fn summary, _state, socket ->
    socket
    |> Phoenix.LiveView.put_flash(:info, "Restored #{summary.succeeded_count} components.")
    |> MishkaGervaz.Table.Web.Events.BulkActionHooks.silence()
  end
end

Suppress the error flash entirely (e.g. log it instead):

on_bulk_action_error :destroy, fn summary, _state, socket ->
  Logger.warning("destroy failed: #{inspect(summary.failed_errors)}")
  MishkaGervaz.Table.Web.Events.BulkActionHooks.silence(socket)
end

Let the default fire and just observe:

on_bulk_action_success :destroy, fn summary, _state, socket ->
  :telemetry.execute([:my_app, :destroy, :success], %{count: summary.succeeded_count})
  socket
end

Customization

Like the sibling handlers in events/, the helpers are overridable:

defmodule MyApp.BulkActionHooks do
  use MishkaGervaz.Table.Web.Events.BulkActionHooks

  # Wrap silence/1 with logging
  def silence(socket) do
    Logger.debug("default bulk flash suppressed")
    super(socket)
  end
end

See MishkaGervaz.Table.Web.Events.BulkActionResult for the summary shape, and MishkaGervaz.Table.Web.Events.BulkActionHandler for the full lifecycle.