Behaviour for cache stores.

Callbacks are invoked from IdempotencyPlug.RequestTracker.

Examples

defmodule RedixStore do
  @behaviour IdempotencyPlug.Store

  @impl true
  def setup(options) do
    name = Keyword.fetch!(options, :redix)

    {:ok, _conn} = Redix.start_link(name: name)

    :ok
  end

  @impl true
  def lookup(request_id, options) do
    redix = Keyword.fetch!(options, :redix)

    case Redix.command(redix, ["GET", request_id]) do
      {:ok, nil} ->
        :not_found

      {:ok, encoded} ->
        {data, fingerprint, expires_at} = :erlang.binary_to_term(encoded, [:safe])

        {data, fingerprint, expires_at}

      {:error, reason} ->
        raise reason
    end
  end

  @impl true
  def insert(request_id, data, fingerprint, expires_at, options) do
    redix = Keyword.fetch!(options, :redix)
    value = :erlang.term_to_binary({data, fingerprint, expires_at})
    expires_in = DateTime.diff(expires_at, DateTime.utc_now(), :second)

    case Redix.command(redix, ["SET", request_id, value, "EX", Integer.to_string(expires_in), "NX"]) do
      {:ok, "OK"} ->
        :ok

      {:ok, nil} ->
        {:error, "key #{request_id} already exists in store"}

      {:error, reason} ->
        {:error, reason}
    end
  end

  @impl true
  def update(request_id, data, expires_at, options) do
    redix = Keyword.fetch!(options, :redix)

    case lookup(request_id, options) do
      :not_found ->
        {:error, "key #{request_id} not found in store"}

      {_data, fingerprint, _expires_at} ->
        value = :erlang.term_to_binary({data, fingerprint, expires_at})
        expires_in = DateTime.diff(expires_at, DateTime.utc_now(), :second)

        case Redix.command(redix, ["SET", request_id, value, "EX", Integer.to_string(expires_in)]) do
          {:ok, "OK"} -> :ok
          {:error, reason} -> {:error, reason}
        end
    end
  end

  @impl true
  def prune(options), do: :ok
end