Helpers for sortable data_table/1 usage in LiveViews.

Use with Corex.DataTable: set sort_by, sort_order, on_sort, and a name on each sortable column (see the Sortable pattern in data_table/1 docs). In the LiveView, call assign_for_sort/3 in mount/3, then handle_sort/3 from the on_sort event handler.

Set :sort_columns in assign_for_sort/3 to whitelist sortable columns on the server. When omitted, :sort_columns is inferred from atom keys on the first row map. Prefer an explicit list when rows carry extra keys not shown in the table.

Example (in-memory rows)

def mount(_params, _session, socket) do
  socket =
    socket
    |> assign(:users, fetch_users())
    |> Corex.DataTable.Sort.assign_for_sort(:users,
      default_sort_by: :id,
      default_sort_order: :asc,
      sort_columns: [:id, :name]
    )

  {:ok, socket}
end

def handle_event("sort", params, socket) do
  {:noreply, Corex.DataTable.Sort.handle_sort(socket, params, :users)}
end

def render(assigns) do
  ~H"""
  <.data_table
    id="users-table"
    rows={@users}
    sort_by={@sort_by}
    sort_order={@sort_order}
    on_sort="sort"
  >
    <:col :let={user} label="ID" name={:id}>{user.id}</:col>
    <:col :let={user} label="Name" name={:name}>{user.name}</:col>
  </.data_table>
  """
end

Example (database-backed rows)

def mount(_params, _session, socket) do
  {rows, total} = MyApp.list_cities(page: 1, page_size: 10, order_by: :name, order_dir: :asc)

  {:ok,
   socket
   |> assign(:cities, rows)
   |> assign(:sort_columns, [:name])
   |> assign(:sort_by, :name)
   |> assign(:sort_order, :asc)
   |> assign(:total, total)}
end

def handle_event("sort", %{"sort_by" => sort_by_param}, socket) do
  case Corex.DataTable.Sort.parse_sort_by(sort_by_param, socket.assigns.sort_columns) do
    {:ok, sort_by} ->
      order =
        if socket.assigns.sort_by == sort_by do
          if socket.assigns.sort_order == :asc, do: :desc, else: :asc
        else
          :asc
        end

      {rows, total} =
        MyApp.list_cities(
          page: 1,
          page_size: socket.assigns.page_size,
          order_by: sort_by,
          order_dir: order
        )

      {:noreply,
       socket
       |> assign(:cities, rows)
       |> assign(:sort_by, sort_by)
       |> assign(:sort_order, order)
       |> assign(:total, total)}

    :error ->
      {:noreply, socket}
  end
end