Collections for Phoenix: records of one kind, with fields your users define, seen as a table, a board, a calendar, a chart or a canvas.

Your app has a module of Cardbox's:

defmodule MyApp.Cardbox do
  use Cardbox, repo: MyApp.Repo, pubsub: MyApp.PubSub
end

and makes collections, adds fields, and reads and writes records with it:

{:ok, books} =
  MyApp.Cardbox.create_collection(%{
    name: "Reading list",
    owner: {"workspace", 42},
    fields: [
      %{name: "Title", type: "text"},
      %{name: "Status", type: "status"},
      %{name: "Rating", type: "number", options: %{format: "integer"}},
      %{name: "Finished", type: "date"}
    ]
  })

{:ok, dune} = MyApp.Cardbox.insert(books, %{"Title" => "Dune", "Status" => "In progress"})

{:ok, reading} =
  MyApp.Cardbox.list(books, %{
    "filter" => %{"field" => "status", "op" => "in_group", "value" => "doing"},
    "sort" => [%{"field" => "title"}]
  })

Options of use Cardbox

• :repo - the Ecto repo of the tables (mix cardbox.gen.migration). Without it, the module defines repo/0, for a repo known only at runtime (a library on Cardbox that takes its host's repo from its config).
• :pubsub - a Phoenix.PubSub, to broadcast each change to the collection's topic (subscribe/1, Cardbox.Event).
• :views - types of views of your own, beside Cardbox's (Cardbox.View): views: ["timeline", "map"]. A view of one is saved, listed and queried as any, and your check_view/3 checks its options; your app draws it. See the Views guide.

Options of the functions

Every function that writes takes :actor, who writes: the person or the agent of your app, whose id (actor_id/1) each record keeps as who made it and changed it last, each event carries, and allow?/3 is asked about.

Every function that reads takes :me (who "me" is in a filter; the actor's id, or any id), :time_zone (where the days of date filters are; UTC unless given) and :now.

Callbacks

Four callbacks have defaults, and your module overrides them:

@impl Cardbox
def actor_id(%MyApp.Accounts.User{id: id}), do: "user:#{id}"

@impl Cardbox
def allow?(%MyApp.Accounts.User{} = user, :change_fields, collection),
  do: MyApp.Permissions.allowed?(user, :manage, collection)

def allow?(_actor, _action, _subject), do: true

@impl Cardbox
def check_view("timeline", %{"start" => _, "end" => _} = options, _collection), do: {:ok, options}
def check_view("timeline", _options, _collection), do: {:error, "a timeline names its start and end fields"}
def check_view(_type, options, _collection), do: {:ok, options}

@impl Cardbox
def after_update(collection, before, record, changed),
  do: {:ok, MyApp.Bills.next(collection, before, record, changed)}